Sub Filter_Select()
'This Macro filters your gantt view to show only the
'tasks that you have selected. It is helpful when you want
'to present a certain groups of tasks or
'you want to show a set of tasks that would
'be difficult to filter for.
'This macro overwrites data in the flag5 field
'Thanks to Michael Edwards for catching the bug in this one.
'version history:
'v1.00 Feb, 2002
'v1.01 Mar 14, 2002 (corrected field used for filter)

'Copyright Jack Dahlgren Feb. 2002

Dim jTasks As Tasks
Dim jTask As Task

'clear the flag field
For Each jTask In ActiveProject.Tasks
    If Not jTask Is Nothing Then
        jTask.Flag5 = "No"
    End If
Next jTask
    
'set the flag field for the selected tasks
Set jTasks = ActiveSelection.Tasks
For Each jTask In jTasks
    If Not jTask Is Nothing Then
        jTask.Flag5 = "Yes"
    End If
Next jTask

'filter to show just the selected tasks
FilterEdit Name:="select", TaskFilter:=True, Create:=True, OverwriteExisting:=True, FieldName:="Flag5", Test:="equals", Value:="Yes", ShowInMenu:=False, ShowSummaryTasks:=False
FilterApply Name:="select"

End Sub